Tresavis

            
/*
 * Es vol mesurar els milimetres de aigua que perd la piscina per evaporació 
 * Fem servir http per visualitzar les dades
 * Placa NodeMCU, sensor ultasonic  HC-SR04
 * magazamatge de dades en format CSV per exportar a un full de calcul
 * SPIFFS Serial Peripheral Interface Flash File System
 */
#include <ESP8266WiFi.h>
#include <ESP8266WebServer.h>
//llibreria file system per gestionar els fitxers en memoria FLASH
#include <FS.h>
#include <TimeLib.h>

#define EchoPin D0
#define TriggerPin D1
#define LedPin D4

///// variables globals ///////
//temps (ms) del procesador encès
static unsigned long tempsMicroActiu;                       
File fitxer;
int interval;
long  alturaCm;
String dataHora;
String iniciar = "no";
//el objecte time_t guarda els segons de la data actual a 1970
time_t tempsSegons;
const char *ssid_AP = "AlturaAP";
const char *password_AP = "12345678";

ESP8266WebServer server(80);
//guardem la pagina web en memoria flach
//formulari amb la data actual
//checkBox per formatajar la flash
//interval de lectures
//data inicial es: Sat Jan 30 2021 11:14:38 GMT+0100 (hora estándar de Europa central)
//la formatejem a 30/01/2021 11:14
static const char INDEX_HTML[] PROGMEM = R"(
  <html>
  <body>
  <form action='/formulari'>
      Data:                    <input type='datetime-local' name='dateTime' id='idData'><br>
      Formatear memoria Flash:  <input type='checkbox' name='format' value='si'><br>
      Interval de Mesures (s): <input type="number" name="interval" min="10" step="10" value="30"><br><br>
                                <input type="submit" value="Enviar">
  </form>
  
  <script>
      var dataActual = new Date();
      var yyyy = dataActual.getFullYear();
      var mm = dataActual.getMonth()+1;         if(mm<10) {mm='0'+mm};
      var dd = dataActual.getDate();            if(dd<10) {dd='0'+dd};
      var hh = dataActual.getHours();           if(hh<10) {hh='0'+hh}; 
      var mn = dataActual.getMinutes();         if(mn<10) {mn='0'+mn}; 
  
      var dataActualFormat =  dd+'-'+mm+'-'+yyyy+'H'+hh+'-'+mn;
      document.getElementById('idData').value = dataActualFormat;
  </script>
  </body>
  </html>
)";

//El servidor agafa la data actual que envia el formulari en mode GET
//converteix el String dataActual a time_t  i el retorna
time_t convertirStringATime(String dataActual){
    //String dataActual = server.arg("dateTime");
    // el format de dataActual es: dd+'-'+mm+'-'+yyyy+'H'+hh+'-'+mn;
    tmElements_t tm;
       tm.Year = dataActual.substring(6,10).toInt()-1970;                         
       tm.Month = dataActual.substring(3,5).toInt();      //6 ????
       tm.Day = dataActual.substring(0,2).toInt();                                
       tm.Hour = dataActual.substring(11,13).toInt();                             
       tm.Minute = dataActual.substring(14,16).toInt();                            
       time_t tempsSegons=makeTime(tm);
       Serial.print("Temps segons->: ");
       Serial.println(String(tempsSegons));//1612092824
    return tempsSegons;                                                              
}
//converteix el tipus time_t a String i el retorna
String convertirTimeAString(time_t temps){
    String dd = day(temps)<10? String("0")+String(day(temps)):String(day(temps));                    //26
    String mm = month(temps)<11? String("0")+String(month(temps)):String (month(temps));         //06
    String yyyy=String(year(temps));
    String hh = hour(temps)<10? String("0")+String(hour(temps)):String(hour(temps));                 //23
    String mn = minute(temps)<10? String("0")+String(minute(temps)):String(minute(temps));           //54
    String dataHora = (dd+"/"+mm+"/"+yyyy+";"+hh+":"+mn+";");                      //26/06/2018;23:54;
    Serial.print("Data Hora->: ");
    Serial.println(dataHora);
    return dataHora;
}

//Funció per formatejar la memoria flash SPIFFS
void format_SPIFFS(){                               
   if (server.arg("format") == "si"){
      Serial.println("Formateix iniciat...");
      digitalWrite(LedPin, LOW); 
      SPIFFS.format();
      Serial.println("Formateix finalizat!");
      digitalWrite(LedPin, HIGH);
   }
}
//llegeix el fitxer global
void llegir_SPIFFS(){
    fitxer = SPIFFS.open("/altura.txt", "r");
    server.streamFile(fitxer, "text/plain");
    fitxer.close();
}

long obtenirAltura() {
   digitalWrite(LedPin, LOW);

   //per generar un tret net posem a LOW 4us
   digitalWrite(TriggerPin, LOW);         
   delayMicroseconds(4);
   //generamos Trigger (tret) de 10us
   digitalWrite(TriggerPin, HIGH);        
   delayMicroseconds(10);
   digitalWrite(TriggerPin, LOW);
   //mesurem el temps entre trets, en microsegons
   long duracio = pulseIn(EchoPin, HIGH);
   //convertim la altura, en cm      
   //alturaCm=(velocitat so * duracio)/2
   // velocitat del so = 0.034cm/microseg 
   // 10/292=0.03424
   long alturaCm = duracio * 10 / 292/ 2;    
   Serial.print("Altura: ");
   Serial.println(alturaCm);
   
   digitalWrite(LedPin, HIGH);
   return alturaCm; 
}


void setup() {
  Serial.begin(115200);
     
  pinMode(LedPin, OUTPUT);
  digitalWrite(LedPin, HIGH); 
  pinMode(TriggerPin, OUTPUT);
  pinMode(EchoPin, INPUT);
  
  WiFi.mode(WIFI_AP);
  WiFi.softAP(ssid_AP, password_AP); 
  Serial.println("WiFi inicializada."); 
  Serial.print("La adreça del AccesPoint es IP: ");
  Serial.println(WiFi.softAPIP()); 
  Serial.println();
  
  SPIFFS.begin();

  //el servidor envia el formulari si el GET es "/"
  server.on("/", []() {                               
      server.send_P(200, "text/html", INDEX_HTML);
  });
  //Si s'envia el formulari, el servidor inicia el proces
  server.on("/formulari", [](){
    //envia el texte inicialitzat
    server.send(200, "text/plain", "Inicializat!");
    //posa la variable global iniciar a si  
    iniciar = "si";
    //obté el inteval de lectures enviat del formulari
    interval = server.arg("interval").toInt();
    Serial.print("interval: ");
    Serial.println(interval);
    //comença a contar el temps en que el micro esta actiu
    tempsMicroActiu = millis();
    //obtenim la variable global dataHora del formulari
    String dataForm=server.arg("dateTime");
    Serial.print("Data hora formulari: ");
    Serial.println(dataForm);
    //la converim al tipus time_t i el guardem com a variable global 
    tempsSegons= convertirStringATime(dataForm);
    //la converim String a time_t i el guardem com a variable global 
    //dataHora=convertirTimeAString(tempsSegons); NO ES NECESARI, PODEM FER SERVIR EL ARGUMENT DEL FORMULARI
    dataHora=dataForm;
    //formateja si en el formulari se clicat formateix, altrament res 
    format_SPIFFS();
    //Si el fitxer altura.txt no existeix el crea de nou i afegeix al final
    fitxer = SPIFFS.open("/altura.txt", "a+");
    //escriu la capçalera del fitxer
    fitxer.println("data;Hora;Altura (cm)");
    fitxer.close();
  });
  //si el GET es /altura llegeix el fitxer altura.txt  
  server.on("/altura", [](){
  llegir_SPIFFS();
  });
  
  server.begin();
  Serial.println("Servidor inicializat.");
}

void loop() {
  server.handleClient();
  //Cada interval s'executa
  if (iniciar == "si" && abs(millis()-tempsMicroActiu) > interval*1000) {     
    tempsSegons = tempsSegons + interval;
    dataHora=convertirTimeAString(tempsSegons);
    alturaCm=obtenirAltura();
    fitxer = SPIFFS.open("/altura.txt", "a+");
    fitxer.print(dataHora);
    fitxer.println(alturaCm);
    fitxer.close();
    tempsMicroActiu = millis(); 
  }
  //Si porta 15 minuts sense incializarse ho fa automáticament
  if (iniciar == "no" && millis()> 900*1000){   
    iniciar="si";
    tempsSegons = 0;
    interval = 60;
    fitxer = SPIFFS.open("/altura.txt", "a+");
    fitxer.println("Data;Hora;Altura (cm)");
    fitxer.close();
  }
}